REM attractor program in basic 
left = 20: w=300
a =.2:b=.2:c=5.7
dt=.04:dt2=dt/2
xmin=1000:xmax=-1000:ymin=1000:ymax=-1000
yn=1
hide=2000
FOR i=1 TO 100000!
REM integration by Heun's method
GOSUB 500
xn0=xn:yn0=yn:zn0=zn
xfn0=xfn:yfn0=yfn:zfn0=zfn
xn=xn0+dt*xfn0
yn=yn0+dt*yfn0
zn=zn0+dt*zfn0
GOSUB 500
xn=xn0+dt2*(xfn+xfn0)
yn=yn0+dt2*(yfn+yfn0)
zn=zn0+dt2*(zfn+zfn0)
IF i < hide GOTO 100
LINE-(left+xfac*(xn-xmin),left+w-yfac*(yn+zn-ymin))
GOTO 200
REM find the range of x and y+z
100 IF xn > xmax THEN xmax=xn
    IF xn < xmin THEN xmin=xn
    IF yn+zn > ymax THEN ymax=yn+zn
    IF yn+zn < ymin THEN ymin=yn+zn
    IF i < hide -1 GOTO 200
REM draw
    xfac =  w/(xmax - xmin)
    yfac = w/(ymax - ymin)
    PSET(left - xfac*(1+xmin),left + w + yfac*ymin)
    LINE-(left+xfac*(1-xmin),left + w + yfac*ymin)
     PSET(left - xfac*(xmin),left + w - yfac*(1-ymin))
    LINE-(left-xfac*(xmin),left + w + yfac*(1+ymin))
    PSET(left + xfac*(xn - xmin),left + w - yfac*(yn+zn-ymin))
200 NEXT i
END
500    xfn = -yn - zn
           yfn = xn + a*yn
           zfn = b + xn*zn - c*zn
RETURN

A Color Rendition of the Output